@echo off
SETLOCAL
REM 2024-04-08
cls

REM Define locale paths
set LPOLYMC=.\PolyMC
set LCOMMON=%LPOLYMC%%\instances\common

REM Define current user PolyMC instances folder
set PROFILE=%APPDATA%
set POLYMC=%PROFILE%\PolyMC
set INSTANCES=%POLYMC%\instances

CALL :doGlobal
CALL :doInstance Ambre
CALL :doInstance Clement
CALL :doInstance Olivier
CALL :doInstance Minecraft

REM Exit with OK
EXIT /B 0

REM Proceed with PolyMC global configuration
:doGlobal

    REM Copy polymc.cfg
    copy /Y %LPOLYMC%\polymc.cfg                %POLYMC%\

    REM Copy instgroups.json
    copy /Y %LPOLYMC%\instances\instgroups.json %POLYMC%\instances\

EXIT /B 0

REM Proceed with PolyMC instance profile
:doInstance

    REM Define PolyMC 'instance'
    set PolyMCinstance=%~1
    set INSTANCE=%INSTANCES%\%PolyMCinstance%
    set MINECRAFT=%INSTANCE%\.minecraft

    REM Create instance folder
    mkdir %INSTANCE%

    REM Define folders: mods, resourcepacks, shaderpacks
    set CONFIG=%MINECRAFT%\config
    set MODS=%MINECRAFT%\mods
    set RESOURCESPACKS=%MINECRAFT%\resourcepacks
    set SHADERPACKS=%MINECRAFT%\shaderpacks

    REM Create folders
    mkdir %CONFIG%\jade

    REM Get current date
    set NOW=%date:~6,4%%date:~3,2%%date:~0,2%

    REM Delete present files
    del /F /Q %MODS%\*.*
    del /F /Q %RESOURCESPACKS%\*.*
    del /F /Q %SHADERPACKS%\*.*

    REM Copy new files
    copy /Y %LCOMMON%\mmc-pack.json                         %INSTANCE%
    copy /Y %LCOMMON%\minecraft\options.txt                 %MINECRAFT%
    copy /Y %LCOMMON%\config\betterf3.json                  %CONFIG%
    copy /Y %LCOMMON%\config\sodium-options.json            %CONFIG%
    copy /Y %LCOMMON%\config\sodium-extra-options.json      %CONFIG%
    copy /Y %LCOMMON%\config\jade.json                      %CONFIG%\jade
    copy /Y %LCOMMON%\mods\*.*                              %MODS%
    copy /Y %LCOMMON%\resourcepacks\*.*                     %RESOURCESPACKS%
    copy /Y %LCOMMON%\shaderpacks\*.*                       %SHADERPACKS%

EXIT /B 0